СтатьиПрограммированиеDelphi

SysListView32. Сортировка своими руками

Автор: Blacksus

Продолжаем тему компонента SysListView32. В этой статье я покажу, как можно сделать программу, которая будет автоматически сортировать элементы при открытии проводника. Причем алгоритм сортировки будет таким, какой зададите вы сами. Для тех, кто еще не знаком с основами взаимодействия программ в системе советую прочитать предыдущую статью SysListView32. Получение списка элементов.

Сразу оговорюсь, что пример рассматриваемый в данной статье подходит только для WindowsXP, у Windows Vista и Windows 2000 немного другая структура иерархии окон на пути к SysListView32.

Большая часть кода будет располагаться в DLL, поэтому для начала создадим ее (File - New - Other - DLL Wizard).

Для того чтобы наша программа могла реагировать на открытие папки проводника, нужно чтобы она перехватывала сообщения, для этого установим ловушку:

procedure RunStopHook(State: Boolean) export; stdcall; begin // включить или выключить ловушку if State then begin // создаем ловушку SysHook := SetWindowsHookEx(WH_GETMESSAGE, @GetMsgProc, HInstance, 0); // если ловушку не удалось создать if SysHook = 0 then MessageBoxEx(0, 'Ловушка не установлена!!!', 'Ошибка', mb_IconStop, 0) else // если ловушка создана MessageBoxEx ( 0, 'Автосортировка включена. '#10#13 + 'Для выхода нажмите Ctrl+X'#10#13 + 'Для показа главного окна нажмите Ctrl+S', 'Сортировка по имени', mb_IconInformation, 0 ); end else begin // пытаемся выключить ловушку if not UnhookWindowsHookEx(SysHook) then // если не удалось MessageBoxEx(0, 'Ловушка не снята!!!', 'Ошибка', mb_IconStop, 0) else // если ловушка снята begin SysHook := 0; MessageBoxEx(0, 'Автосортировка выключена', 'Сортировка по имени', mb_IconInformation, 0); end; end; end;

Рассмотрим код поближе. Если нам нужно установить ловушку, то при помощи функции SetWindowsHookEx устанавливаем ее. В качестве параметров функция принимает тип ловушки, в нашем случае WH_GETMESSAGE, что означает перехват сообщений. Следующий параметр является ссылкой на процедуру, которая будет вызываться каждый раз при срабатывании ловушки. Следующий параметр определяет DLL, в которой располагается функция обработки ловушки. И последний параметр определяет поток, в котором расположена функция. Функция вернет хэндл созданной ловушки, если удалось создать ее, либо вернет 0 при неудаче. Далее мы проверяем возвращенное значение и выдаем соответствующее сообщение.
Если нам нужно снять ловушку, то используем функцию UnhookWindowsHookEx, которая в качестве параметра принимает хэндл ловушки и возвращает True при удачном снятии ловушки или False при неудаче. Проверяем это значение и выдаем соответствующее сообщение.

Вышеописанную процедуру нужно экспортировать из DLL, для этого в самом конце нужно добавить код:

Далее рассмотрим код функции, которая вызывается при срабатывании ловушки:

function GetMsgProc(code : integer; wParam : word; lParam : longint): longint; stdcall; var Wnd: Hwnd; pid: longint; ph,mh: THandle; cm: Cardinal; TempArr: array [0..max_path] of Char; begin // вызываем следующую ловушку Result := CallNextHookEx(SysHook, Code, wParam, lParam); // проверяем код if code = HC_ACTION then begin // если пришло сообщение об обновлении if TMsg(Pointer(lParam)^).message = WM_REFRESH then begin // запоминаем хэндл окна Wnd := TMsg(Pointer(lParam)^).hwnd; // получаем идентификатор процесса по его окну GetWindowThreadProcessId(Wnd, @pid); // открываем процесс для чтения и получения информации ph := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, false, pid); // если удалось открыть его if ph > 0 then begin // получаем хэндлы на модули процесса EnumProcessModules(ph, @mh, 4, cm); // получаем имя файла процесса GetModuleFileNameEx(ph, mh, TempArr, SizeOf(TempArr)); // сравниваем его с именем проводника if LowerCase(ExtractFileName(string(TempArr))) = 'explorer.exe' then begin // получаем хэндл на SysListView32 проводника ListViewWnd := ListView_GetHandle(Wnd); // посылаем сообщение о сортировке без процедуры SendMessage(ListViewWnd, LVM_SORTITEMS, 0, 0); // посылаем сообщение о сортировке с ссылкой на нашу процедуру SendMessage(ListViewWnd, LVM_SORTITEMS, 0, Integer(@CompareFunc)); end; end; // закрываем процесс CloseHandle(ph); end; end; end; end;

Сначала нужно вызвать следующую ловушку, т.е. передать ей управление, пока мы тут будем обрабатывать свои данные. Если код равен HC_ACTION, значит мы можем обработать это сообщение. Далее проверяем, чтобы это сообщение было то, которое нам нужно, а именно WM_REFRESH. Стоит отметить, что WM_REFRESH это не стандартная системная константа, а программно заданная:

const WM_REFRESH = 1211;

Это внутреннее сообщение проводника. Не стоит вдаваться в подробности, каким именно образом это сообщение было отсеяно из сотни других, конечно, это было не легко :).
Далее выделяем из сообщения хэндл окна, которое его послало. При помощи этого хэндла узнаем процесс, открываем его и получаем имя его файла. Проверяем что имя файла explorer.exe. Если это так, то получаем хэндл на SysListView32 этого окна:

function ListView_GetHandle(Wnd: HWND): THandle; begin Result := FindWindowEx(Wnd, 0, 'DUIViewWndClassName', nil); Result := FindWindowEx(Result, 0, 'DirectUIHWND', nil); Result := FindWindowEx(Result, 0, 'CtrlNotifySink', nil); Result := FindWindowEx(Result, 0, 'SysListView32', nil); end;

и посылаем 2 сообщения о сортировке. Отмечу, что нужно послать именно 2 сообщения о сортировке. Первое должно быть пустое, а второе со ссылкой на нашу функцию сортировки. Первое сообщение выстроит все элементы по имени, т.е. это некая подготовка, а уже второе сообщение отсортирует их как нам надо. По непонятным мне причинам сортировка в компоненте реализована именно так, имхо это очень криво со стороны разработчиков, особенно учитывая то, что в документации о такой "особенности" не написано.

Далее рассмотрим саму функцию сортировки:

function CompareFunc(lParam1, lParam2, lParamSort: Integer): Integer stdcall; var FindInfo: TLVFINDINFO; Index, l, i: integer; Arr, Arr2: array [0..max_path] of Char; Item1, Item2: string; begin // обнуляем структуру ZeroMemory(@FindInfo, SizeOf(FindInfo)); // заполняем ее FindInfo.flags := LVFI_PARAM; FindInfo.lParam := lParam1; // ищем элемент Index := ListView_FindItem(ListViewWnd, 0, FindInfo); if Index = -1 then Index := 0; // получаем текст найденного элемента ListView_GetItemText(ListViewWnd, Index, 0, Arr, SizeOf(Arr)); Item1 := string(Arr); // проделываем ту же операци для поиска второго элемента ZeroMemory(@FindInfo, SizeOf(FindInfo)); FindInfo.flags := LVFI_PARAM; FindInfo.lParam := lParam2; Index := ListView_FindItem(ListViewWnd, 0, FindInfo); if Index = -1 then Index := 0; ListView_GetItemText(ListViewWnd, Index, 0, Arr2, SizeOf(Arr2)); Item2 := string(Arr2); // удаляем разницу в регистре, переводим оба в верхний Item1 := UpperCase(Item1); Item2 := UpperCase(Item2); // выбираем самый короткий элемент if Length(Item1) <= Length(Item2) then l := Length(Item1) else l := Length(Item2); Result := 0; // цикл сравнения каждого элемента строки for i := 1 to l do begin if Item1[i] = Item2[i] then continue; if Item1[i] > Item2[i] then begin Result := 1; Break; end else begin Result := -1; Break; end; end; end;

Эта функция имеет 3 параметра: lParam1 - ссылка на первый элемент, lParam2 - ссылка на второй элемент, lParamSort - программно заданное значение, которое передается в функцию сортировки. Оно задается при посылке сообщения о сортировке и обычно говорит о виде сортировки, но т.к. у нас только сортировка по имени, то мы его не используем.
Так же эта функция должна возвратить результат. Она возвращает 0, если элементы не нужно менять местами, положительное значение, если первый элемент должен быть впереди второго, и отрицательное значение, если первый элемент должен быть позади второго.
Вначале обнуляем и заполняем структуру, которая будет передана в функцию поиска элемента. Затем при помощи этой функции находим индекс элемента, а по индексу его имя. Делаем тоже самое для поиска второго элемента. Переводим оба элемента в верхний регистр. Выбираем самый короткий элемент, чтобы использовать его длину в цикле сравнения. Присваиваем результату 0, т.е. по-умолчанию оставляем элементы на их местах. Далее в цикле проверяем оба элемента посимвольно до первого различия, и, исходя из этой проверки, присваиваем результату положительное или отрицательное значение.

Не могу сказать точно о методе сортировки, применяемом этим компонентом, но, похоже, что каждый элемент сравнивается с каждым.

Теперь в DLL надо добавить глобальные переменные:

var SysHook: HHook; ListViewWnd: HWND;

и на этом создание DLL можно закончить. Сохраняем, компилируем ее и переименовываем файл в "AutoSortByName.dll".

Теперь перейдем к созданию программы, которая будет использовать эту библиотеку.

В разделе implementation указываем экспортируемую функцию:

В этом примере я сделал так, что при запуске программы форма скрывается, а ловушка устанавливается автоматически. Для снятия ловушки или показа окна программы используются горячие клавиши. Естественно, что я так же сделал "облегченную" версию примера, в которой ловушка устанавливается и снимается по нажатию на кнопку.

Рассмотрим более сложную и красивую версию примера.

Для события OnShow формы указываем следующий код:

procedure TAutoSortForm.FormShow(Sender: TObject); begin SetTimer(Handle, 1, 10, @Timer); end;

Это таймер, который будет скрывать форму через 10 миллисекунд. Он сделан потому, что свойство Visible у формы нельзя менять при событии OnShow. Вот код самого таймера:

procedure Timer(var Msg: TMessage); begin KillTimer(Form1.Handle, 1); ShowWindow(Form1.Handle, SW_HIDE); ShowWindow(Application.Handle, SW_HIDE); end;

Этот таймер при срабатывании останавливает себя, а затем скрывает форму.

Код при создании формы:

procedure TAutoSortForm.FormCreate(Sender: TObject); begin AutoSort_HK_Close := GlobalAddAtom('AutoSort_HK_Close'); RegisterHotKey(Handle, AutoSort_HK_Close, MOD_CONTROL, 88); AutoSort_HK_Show := GlobalAddAtom('AutoSort_HK_Show'); RegisterHotKey(Handle, AutoSort_HK_Show, MOD_CONTROL, 83); RunStopHook(true); end;

В этой процедуре регистрируем 2 горячие клавиши, затем устанавливаем ловушку.

Код при уничтожении формы:

procedure TAutoSortForm.FormDestroy(Sender: TObject); begin UnRegisterHotKey(Handle, AutoSort_HK_Close); UnRegisterHotKey(Handle, AutoSort_HK_Show); RunStopHook(false); end;

При уничтожении формы удаляем горячие клавиши и снимаем ловушку.

Так же нужно добавить процедуру, наследуемую от TForm, которая будет принимать сообщения, посланные форме:

procedure TAutoSortForm.WndProc(var Msg: TMessage); begin with Msg do if Msg = WM_HOTKEY then begin if WParam = AutoSort_HK_Close then Application.Terminate else if WParam = AutoSort_HK_Show then begin ShowWindow(Form1.Handle, SW_SHOW); ShowWindow(Application.Handle, SW_SHOW); end; end; inherited; end;

Проверяем, что это сообщение о нажатии горячей клавиши. Далее проверяем, если нажата комбинация Ctrl+X, то закрываем приложение, а если нажаты Ctrl+S, то показываем окно.

Теперь сохраняем проект, компилируем и запускам. При открытии любой папки или при нажатии в этой папке кнопки обновления F5, все элементы отсортируются по имени. Важно отметить, что элементы сортируются независимо от того файл это или папка.

Полная версия примера:

Исходный код примера можно скачать тут, а программу тут.

"Облегченная" версия примера:

Исходный код примера можно скачать тут, а программу тут.